summarylogtreecommitdiffstats
path: root/PKGBUILD
blob: 1506cb8643f804857593dc11d941eed0b99f1748 (plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
# Maintainer: Daniel M. Capella <polyzen@archlinux.info>
# Maintainer: Johannes Löthberg <johannes@kyriasis.com>

pkgname=pacman-contrib-git
_gitname=pacman-contrib
pkgver=0.0.1.r8.g86adc7b
pkgrel=1
pkgdesc='pacman contributions (Git version)'
url=https://git.archlinux.org/$_gitname.git
arch=('i686' 'x86_64')
license=('GPL')
depends=('pacman-git') # Change to 'pacman' after its next release
makedepends=('asciidoc' 'git')
provides=("$_gitname")
replaces=("$_gitname")
source=("git+$url")
sha512sums=('SKIP')

pkgver() {
  cd $_gitname
  git describe --long --tags | sed -r 's/^v//; s/([^-]*-g)/r\1/; s/-/./g'
}

build() {
  cd $_gitname
  ./autogen.sh
  ./configure --prefix=/usr --sysconfdir=/etc \
    --localstatedir=/var --enable-git-version \
    --with-vim-dir=/usr/share/vim/vimfiles
  make V=1
}

check() {
  make -C $_gitname check
}

package() {
  cd $_gitname
  make DESTDIR="$pkgdir" install
}

# vim:set ts=2 sw=2 et: