summarylogtreecommitdiffstats
path: root/PKGBUILD
blob: 032bc3afb618e5e9dbfcf81ad776858698e79928 (plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
# Maintainer: aksr <aksr at t-com dot me>
# Maintainer: Caleb Maclennan <caleb@alerque.com>

_pkgname=libertinus
pkgname="otf-$_pkgname-git"
pkgver=6.11.r19.g61f0348
pkgrel=1
pkgdesc='The Libertinus font family, a fork of Linux Libertine and Biolinum with OpenType math'
arch=('any')
url="https://github.com/alif-type/$_pkgname"
license=('OFL')
provides=("${pkgname%-git}")
conflicts=("${pkgname%-git}")
_py_deps=('fonttools'
          'fs'
          'lxml'
          'skia-pathops'
          'ufo2ft'
          'ufolib2>=0.6.2')
makedepends=('mupdf-tools'
             'psautohint'
             'python'
             "${_py_deps[@]/#/python-}"
             'sfd2ufo'
             'texlive-core')
source=("$pkgname::git+$url")
md5sums=('SKIP')

pkgver() {
  cd "$pkgname"
  git describe --long --tags | sed 's/^v//;s/\([^-]*-g\)/r\1/;s/-/./g'
}

prepare() {
  cd "$pkgname"
  sed -i -e '/^DIST/s/=/?=/;/zip -rq/d' Makefile
}

build() {
  cd "$pkgname"
  make
  make dist DIST=dist
}

package() {
  cd "$pkgname/dist"
  install -Dm644 -t "$pkgdir/usr/share/fonts/OTF/" "${_pkgname^}"*.otf
  install -Dm644 -t "$pkgdir/usr/share/licenses/$pkgname" OFL.txt AUTHORS.txt
  install -Dm644 -t "$pkgdir/usr/share/doc/$pkgname/" README.txt FONTLOG.txt documentation/*
}