summarylogtreecommitdiffstats
path: root/PKGBUILD
blob: 208792def731aff8a97d6260025b9774b0a9b032 (plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
# Maintainer: alex19EP <aarnaarn2@gmail.com>
# Contributor: Steve Holmes <steve.holmes88@gmail.com>
# Contributor: William Rea <sillywilly@gmail.com>

pkgname=orca-git
pkgver=3.35.3.r39.g444106ded
pkgrel=1
pkgdesc="Screen reader for individuals who are blind or visually impaired (development version)"
arch=(any)
license=('LGPL')
url="https://wiki.gnome.org/Projects/Orca"
depends=('gtk3'
	'at-spi2-atk'
	'python-atspi'
	'python-dbus'
	'python-xdg'
	'speech-dispatcher'
	'liblouis'
	'brltty'
	'xorg-xmodmap'
	'gst-plugins-base'
	'gst-plugins-good')
makedepends=('git'
	'yelp-tools'
	'itstool'
	'intltool')
provides=('orca')
conflicts=('orca')
source=(${pkgname}::'git+https://gitlab.gnome.org/GNOME/orca.git')
md5sums=('SKIP')

pkgver() {
	cd "${srcdir}/${pkgname}"
	# cutting off 'ORCA_' prefix that presents in the git tag
	git describe --long | sed 's/^ORCA_//;s/\([^-]*-g\)/r\1/;s/_/-/g;s/-/./g'
}

prepare() {
	cd "${srcdir}/${pkgname}"
	./autogen.sh --prefix=/usr --sysconfdir=/etc --localstatedir=/var
}

build() {
	cd "${srcdir}/${pkgname}"
	make
}

package() {
	cd "${srcdir}/${pkgname}"
	make DESTDIR="${pkgdir}" install
}