summarylogtreecommitdiffstats
path: root/PKGBUILD
blob: 70969aa5b54a8a81a7d2264b7bfe2d0426b7cdcc (plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
# This module was originally made for IBM TSS (aur/ibm-tss).
#
# As of 3.0.0 it *can* be built against the Intel TSS (community/tpm2-tss), but
# in that case you should probably be using community/tpm2-tss-engine instead.
#
# For that reason the default is still to use IBM TSS, but if you prefer, you
# can run `makepkg use_ibm_tss=0` to build against the Intel one.
use_ibm_tss=1

pkgname=openssl-tpm2-engine
pkgver=3.0.1
pkgrel=1
pkgdesc="OpenSSL engine for TPM-backed keys using IBM's TPM2 software stack"
arch=(x86_64)
url="https://git.kernel.org/pub/scm/linux/kernel/git/jejb/openssl_tpm2_engine.git"
license=('LGPL2.1')
if (( use_ibm_tss )); then
  depends=('openssl' 'ibm-tss')
else
  depends=('openssl' 'tpm2-tss')
fi
makedepends=('help2man')
checkdepends=('swtpm')
_commit=7cffabd7ddff8aa762256fc6195e2d8b656ab6f2
source=("$pkgname::git+https://git.kernel.org/pub/scm/linux/kernel/git/jejb/openssl_tpm2_engine.git#commit=$_commit")
sha256sums=('SKIP')

pkgver() {
  cd $pkgname
  git describe | sed "s/^v//; s/-/.r/; s/-/./"
}

prepare() {
  cd $pkgname
  autoreconf -fi
}

build() {
  cd $pkgname
  ./configure --prefix=/usr --sysconfdir=/etc --localstatedir=/var
  make
}

#check() {
#  cd $pkgname
#  make check
#}

package() {
  cd $pkgname
  make DESTDIR="$pkgdir" install
}

# vim: ts=2:sw=2:et