summarylogtreecommitdiffstats
path: root/PKGBUILD
blob: fcd7e0cabc237efdef924afb767bff8e1d9644aa (plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
# Maintainer: Chocobo1 <chocobo1 AT archlinux DOT net>

pkgname=openexr-git
pkgver=3.0.0.beta.r7.ge46ac0a7
pkgrel=1
pkgdesc="Reference implementation of the EXR format"
arch=('i686' 'x86_64')
url="https://www.openexr.com/"
license=('BSD' 'custom')
depends=('gcc-libs' 'zlib')
makedepends=('git' 'cmake' 'boost' 'chrpath' 'freeglut' 'python' 'python-numpy')
optdepends=('boost-libs: python support'
            'python: python support')
provides=('openexr')
conflicts=('openexr' 'ilmbase')
replaces=('ilmbase')
source=("git+https://github.com/AcademySoftwareFoundation/openexr.git")
sha256sums=('SKIP')


pkgver() {
  cd "openexr"

  git describe --long --tags | sed 's/^v//;s/\([^-]*-g\)/r\1/;s/-/./g'
}

build() {
  cd "openexr"

  cmake \
    -B "_build" \
    -DCMAKE_BUILD_TYPE=Release \
    -DCMAKE_INSTALL_PREFIX="/usr" \
    ./
  make -C "_build"
}

check() {
  cd "openexr"

  #make -C "_build" test
}

package() {
  cd "openexr"

  make -C "_build" DESTDIR="$pkgdir" install
  install -Dm644 {LICENSE.md,PATENTS} -t "$pkgdir/usr/share/licenses/openexr"
}