summarylogtreecommitdiffstats
path: root/PKGBUILD
blob: c480b280301958418f50c4669264db5b9b32301c (plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
# $Id$
# Maintainer: Jens Staal <staal1978@gmail.com>
# adapted from "newsboat" package:
# Maintainer: Jaroslav Lichtblau <svetlemodry@archlinux.org>
# Contributor: Sven Pfleiderer <pfleidi@roothausen.de>

pkgname=newsboat-git
pkgver=r2.12.r143.gb791ff16
pkgrel=1
pkgdesc="An RSS/Atom feed reader for text terminals"
arch=('x86_64')
url="https://newsboat.org/"
license=('custom: MIT')
depends=('curl' 'json-c' 'libxml2' 'sqlite' 'stfl')
makedepends=('swig' 'gettext' 'asciidoc')
provides=('newsboat')
conflicts=('newsboat')
replaces=('newsbeuter')
options=('!emptydirs')
source=($pkgname::git+https://github.com/newsboat/newsboat.git)
sha256sums=('SKIP')


pkgver() {
  cd "${srcdir}"/$pkgname
  git describe --long --tags | sed 's/\([^-]*-g\)/r\1/; s/-/./g'
}

build() {
  cd "${srcdir}"/$pkgname

  make prefix=/usr
  make doc
}

package() {
  cd "${srcdir}"/$pkgname

  make prefix=/usr DESTDIR="${pkgdir}" install
  install -Dm644 LICENSE "${pkgdir}"/usr/share/licenses/$pkgname/LICENSE
}