summarylogtreecommitdiffstats
path: root/PKGBUILD
blob: 25e79871fe05dce2405498500c8446d6601bcd7b (plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
# Maintainer: Chocobo1 <chocobo1 AT archlinux DOT net>

pkgname=nettle-git
pkgver=3.3.r26.gdcda81d7
pkgrel=1
pkgdesc="A cryptographic library that is designed to fit easily in any context"
arch=('i686' 'x86_64')
url="https://www.lysator.liu.se/~nisse/nettle/"
license=('GPL' 'LGPL')
depends=('glibc' 'gmp')
makedepends=('git')
provides=('nettle')
conflicts=('nettle')
source=("git+https://git.lysator.liu.se/nettle/nettle.git")
sha256sums=('SKIP')


pkgver() {
  cd "nettle"

  git describe --long --tags | sed 's/^[_a-z]*\([0-9.]*\)[^-]*/\1/;s/\([^-]*-g\)/r\1/;s/-/./g'
}

build() {
  cd "nettle"

  ./.bootstrap
  ./configure --prefix="/usr" --disable-documentation
  make
}

check() {
  cd "nettle"

  make check
}

package() {
  cd "nettle"

  make DESTDIR="$pkgdir" install
}