summarylogtreecommitdiffstats
path: root/PKGBUILD
blob: ec6a27fe9d73250ab7567c330b69ceca275ee840 (plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
# Maintainer: Joost Bremmer <toost.b@gmail.com>
# Contributor: Alexander F Rødseth <xyproto@archlinux.org>
# Contributor: olantwin <olantwin@gmail.com>

pkgbase=neovim-airline
pkgname=('neovim-airline' 'neovim-airline-themes')
arch=('any')
license=('MIT')
makedepends=('git')
groups=('neovim-plugins')

#temp pkgver variables
pkgver=0.10
pkgrel=0
_themes_pkgver=r1321.3bfe1d0
source=("${pkgname[0]}::git://github.com/vim-airline/${pkgname[0]#neo}.git#tag=v$pkgver"
        "${pkgname[1]}::git://github.com/vim-airline/${pkgname[1]#neo}.git#commit=${_themes_pkgver#*.}")
sha256sums=('SKIP' 'SKIP')

# Neovim install dir
_installpath="usr/share/nvim/runtime"

package_neovim-airline() {
  # set package local variables
  pkgdesc='Lean & mean statusline/tabline for Neovim'
  url='https://github.com/vim-airline/vim-airline'
  depends=('neovim')
  optdepends=('neovim-airline-themes: Various themes')
  install='nvim-doc.install'

  cd "${pkgname[0]}"
  install -Dvm755 doc/airline.txt "$pkgdir/$_installpath/doc/airline.txt"
  install -Dvm755 plugin/airline.vim "$pkgdir/$_installpath/plugin/airline.vim"
  install -dv "$pkgdir/$_installpath/autoload"
  install -dv "$pkgdir/$_installpath/t"
  cp -R autoload/* "$pkgdir/$_installpath/autoload"
  cp -R t/* "$pkgdir/$_installpath/t"
  install -Dvm644 LICENSE "$pkgdir/usr/share/licenses/${pkgname[0]}/LICENSE"

}

package_neovim-airline-themes(){
  # set package local variables
  url='https://github.com/vim-airline/vim-airline-themes'
  pkgdesc='Themes for neovim-airline'
  depends=('neovim-airline' 'neovim')

  cd "${pkgname[1]}"
  install -dv "$pkgdir/$_installpath"
  cp -r --no-preserve=owner autoload plugin "$pkgdir/$_installpath"
  install -Dm644 LICENSE "$pkgdir/usr/share/licenses/${pkgname[1]}/LICENSE"
}

# getver: raw.githubusercontent.com/vim-airline/vim-airline/master/CHANGELOG.md
# vim:set ts=2 sw=2 et: