summarylogtreecommitdiffstats
path: root/PKGBUILD
blob: 3eaa42f348de9df531fb9767ff5b19c7521752fb (plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
pkgname=mingw-w64-pango
pkgver=1.40.10
pkgrel=1
_commit=fe68dd173cc34c160b2f6451aa93682163813eba  # tags/1.40.10^0
pkgdesc="A library for layout and rendering of text (mingw-w64)"
arch=(any)
url="http://www.pango.org"
license=("LGPL")
makedepends=(mingw-w64-configure gtk-doc git)
depends=(mingw-w64-harfbuzz mingw-w64-cairo)
options=(staticlibs !strip !buildflags !emptydirs)
source=("git+https://git.gnome.org/browse/pango#commit=$_commit"
"0001-no-unconditional-xft-please.all.patch")
sha256sums=('SKIP'
            'bebab6128258d300e677df0751177f5c30235d0a49c150d97987d0f00b309f35')
_architectures="i686-w64-mingw32 x86_64-w64-mingw32"

pkgver() {
  cd "$srcdir/pango"
  git describe --tags | sed 's/-/+/g'
}

prepare() {
	cd "$srcdir/pango"
	patch -p1 -i ${srcdir}/0001-no-unconditional-xft-please.all.patch
	NOCONFIGURE=1 ./autogen.sh
	sed -i 's/have_libthai=true/have_libthai=false/' configure
}

build() {
	cd "$srcdir/pango"
	for _arch in ${_architectures}; do
		mkdir -p build-${_arch} && pushd build-${_arch}
		${_arch}-configure \
			--disable-introspection \
			--disable-debug
		make
		popd
	done
}



package() {
	for _arch in ${_architectures}; do
		cd "${srcdir}/pango/build-${_arch}"
		make -j1 DESTDIR="$pkgdir" install
		find "$pkgdir/usr/${_arch}" -name '*.exe' -exec ${_arch}-strip {} \;
		find "$pkgdir/usr/${_arch}" -name '*.dll' -exec ${_arch}-strip --strip-unneeded {} \;
		find "$pkgdir/usr/${_arch}" -name '*.a' -o -name '*.dll' | xargs ${_arch}-strip -g
	done
}