summarylogtreecommitdiffstats
path: root/PKGBUILD
blob: 3c22219db4a7210ab44868c03f4568dec88d32a9 (plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
# Maintainer: Steffen Weber <-boenki-gmx-de->
# Contributor: juan pablo gonzalez <lord_jotape@yahoo.com.ar> #Thanks to keenerd and ivo
 
pkgname=libxspf
pkgver=1.2.0
pkgrel=4
pkgdesc="Library that helps applications to read and write XSPF playlists"
url="http://libspiff.sourceforge.net/"
arch=('x86_64')
license=('custom')
depends=('uriparser' 'expat' 'gcc-libs')
source=(https://downloads.sourceforge.net/libspiff/$pkgname-$pkgver.tar.bz2)
md5sums=('eceb3bf8fd4af3b09ea06c5c029cd647')

prepare() {
  sed -i '45i #include <unistd.h> // getcwd' \
   "$pkgname-$pkgver/examples/read/read.cpp"
}

build() {
  cd "$pkgname-$pkgver"
  ./configure --prefix=/usr --disable-test
  make
}

package() {
  cd "$pkgname-$pkgver"
  make DESTDIR="$pkgdir" install
  install -Dm644 COPYING "$pkgdir/usr/share/licenses/$pkgname/LICENSE"
}