summarylogtreecommitdiffstats
path: root/PKGBUILD
blob: 41edcd2c5c858a96a57df7b552d1a07699b4d82d (plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
# Maintainer: Kyle Keen <keenerd@gmail.com>

pkgname=libvolk-git
_gitname=volk
pkgver=v2.4.1
pkgrel=1
pkgdesc="The Vector-Optimized Library of Kernels from Gnuradio"
arch=('i686' 'x86_64')
url="http://libvolk.org/"
license=('GPL3')
depends=('gcc-libs' 'boost-libs' 'orc' 'python' 'python-six')
makedepends=('git' 'boost' 'cmake' 'python-mako')
source=("git://github.com/gnuradio/volk.git")
md5sums=('SKIP')
conflicts=('libvolk')
provides=('libvolk')

# doxygen for docs

pkgver() {
  cd "$srcdir/$_gitname"
  git describe --always | sed 's|-|.|g'
}

prepare() {
  cd "$srcdir/$_gitname"
  git submodule update --init
}

build() {
  export PYTHON=python3
  cd "$srcdir/$_gitname"

  mkdir -p build
  cd build
  cmake \
    -DPYTHON_EXECUTABLE=$(which python3) \
    -DCMAKE_INSTALL_PREFIX=/usr -Wno-dev ../
  make
}

check() {
  cd "$srcdir/$_gitname/build"
  export PYTHON=python3
  if [[ "$CARCH" == "x86_64" ]]; then
    make test
  fi
}

package() {
  cd "$srcdir/$_gitname/build"
  make DESTDIR="$pkgdir" install
}