summarylogtreecommitdiffstats
path: root/PKGBUILD
blob: 5be32c76c5887b288045557674058ddf2312ec28 (plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
# Maintainer: Chocobo1 <chocobo1 AT archlinux DOT net>

pkgname=libunistring-git
pkgver=0.9.7.r5.gdd8fabb
pkgrel=2
pkgdesc="A library provides functions for manipulating Unicode strings and for manipulating C strings"
arch=('i686' 'x86_64')
url="https://www.gnu.org/software/libunistring/"
license=('GPL3')
depends=('glibc')
makedepends=('git' 'gperf')
provides=('libunistring')
conflicts=('libunistring')
options=('staticlibs')
source=("git+https://git.savannah.gnu.org/git/libunistring.git")
sha256sums=('SKIP')


pkgver() {
  cd "libunistring"

  git describe --long --tags | sed 's/^v//;s/\([^-]*-g\)/r\1/;s/-/./g'
}

build() {
  cd "libunistring"

  ./autogen.sh
  ./configure --prefix="/usr"
  make
}

check() {
  cd "libunistring"

  make check
}

package() {
  cd "libunistring"

  make DESTDIR="$pkgdir" install
}