summarylogtreecommitdiffstats
path: root/PKGBUILD
blob: 5759880b0cdf0ed24c3fc233e68393fa18f20daa (plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
# Maintainer: Chocobo1 <chocobo1 AT archlinux DOT net>

pkgname=libsamplerate-git
pkgver=r437.g0668431
pkgrel=1
pkgdesc="A Sample Rate Converter for audio"
arch=('i686' 'x86_64')
url="http://www.mega-nerd.com/SRC/index.html"
license=('BSD')
depends=('glibc' 'libsndfile')
makedepends=('git')
checkdepends=('fftw')
provides=('libsamplerate')
conflicts=('libsamplerate')
options=('staticlibs')
source=("git+https://github.com/erikd/libsamplerate.git")
sha256sums=('SKIP')


pkgver() {
  cd "libsamplerate"

  _rev=$(git rev-list --count --all)
  _hash=$(git rev-parse --short HEAD)
  printf "r%s.g%s" "$_rev" "$_hash"
}

build() {
  cd "libsamplerate"

  ./autogen.sh
  ./configure --prefix="/usr"
  make
}

check() {
  cd "libsamplerate"

  make check
}

package() {
  cd "libsamplerate"

  make DESTDIR="$pkgdir" install
  install -Dm644 "COPYING" "$pkgdir/usr/share/licenses/libsamplerate/COPYING"
}