summarylogtreecommitdiffstats
path: root/PKGBUILD
blob: 9ab6d18b49da3de06f0d3643666f7beee4651bf4 (plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
# Maintainer: Chocobo1 <chocobo1 AT archlinux DOT net>

pkgname=libquicktime-git
pkgver=r971.gfff99cd
pkgrel=1
pkgdesc="Library for reading and writing quicktime files"
arch=('i686' 'x86_64')
url="http://libquicktime.sourceforge.net/"
license=('LGPL')
depends=('glibc' 'alsa-lib' 'faac' 'faad2' 'gtk2' 'lame' 'libjpeg-turbo' 'libxaw'
         'libxv' 'schroedinger'
         'libavcodec.so' 'libswscale.so' 'libvorbisenc.so' 'libvorbisfile.so'
         'libvorbis.so' 'libx264.so')
makedepends=('git' 'doxygen' 'mesa-libgl')
provides=('libquicktime')
conflicts=('libquicktime')
source=("git+https://git.code.sf.net/p/libquicktime/git")
sha256sums=('SKIP')


pkgver() {
  cd "git"

  _rev=$(git rev-list --count --all)
  _hash=$(git rev-parse --short HEAD)
  printf "r%s.g%s" "$_rev" "$_hash"
}

build() {
  cd "git"

  ./autogen.sh
  ./configure \
    --prefix="/usr" \
    --enable-gpl \
    --with-ffmpeg \
    --with-x264
  make
}

package() {
  cd "git"

  make DESTDIR="$pkgdir" install
}