summarylogtreecommitdiffstats
path: root/PKGBUILD
blob: bc2caab653138f49a9fbc24833ab51d198ef3918 (plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
# Maintainer: carstene1ns <arch carsten-teibes de> - http://git.io/ctPKG

pkgname=libntfs-wii
pkgver=2013.1.13
pkgrel=2
pkgdesc='NTFS-3G filesystem access library (for Nintendo Gamecube/Wii homebrew development)'
arch=('any')
url='https://sourceforge.net/projects/libntfs-wii/'
license=('GPL')
options=(!strip staticlibs)
depends=('devkitppc')
makedepends=('svn')
source=($pkgname-$pkgver::"svn+http://svn.code.sf.net/p/libntfs-wii/code/tags/libntfs-$pkgver")
md5sums=('SKIP')

prepare() {
  cd $pkgname-$pkgver

  # fix install directory (not a portlib)
  sed 's|$(PORTLIBS)|$(DEVKITPRO)/libogc|;s|ogc/lib$|&/wii|' -i source/Makefile
}

build() {
  cd $pkgname-$pkgver

  # set environment
  source /etc/profile.d/devkitppc.sh

  make
}

package() {
  cd $pkgname-$pkgver

  export DEVKITPRO="$pkgdir/opt/devkitpro"
  install -d "$DEVKITPRO"/libogc/{include,lib/{cube,wii}}
  make wii-install cube-install
}