summarylogtreecommitdiffstats
path: root/PKGBUILD
blob: b240dbb99edc88c95da0c7ac9bbe21ac9b5df922 (plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
# Maintainer: Chocobo1 <chocobo1 AT archlinux DOT net>

pkgname=libmd-git
pkgver=1.0.3.r12.gd9c4c7f
pkgrel=2
pkgdesc="Message digest functions from BSD systems"
arch=('i686' 'x86_64')
url="https://www.hadrons.org/software/libmd/"
license=('custom')
depends=('glibc')
makedepends=('git')
provides=('libmd')
conflicts=('libmd')
options=('staticlibs')
source=("git+https://git.hadrons.org/git/libmd.git")
sha256sums=('SKIP')


pkgver() {
  cd "libmd"

  git describe --long --tags | sed 's/^v//;s/\([^-]*-g\)/r\1/;s/-/./g'
}

build() {
  cd "libmd"

  ./autogen
  ./configure \
    --prefix="/usr"
  make
}

check() {
  cd "libmd"

  make check
}

package() {
  cd "libmd"

  make DESTDIR="$pkgdir" install
  install -Dm644 "COPYING" -t "$pkgdir/usr/share/licenses/libmd"
}