summarylogtreecommitdiffstats
path: root/PKGBUILD
blob: e9eac6297773388d3144edf537978610a1ea8c1f (plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
# Merged with official ABS libksieve PKGBUILD by João, 2021/02/02 (all respective contributors apply herein)
# Maintainer: João Figueiredo <jf.mundox@gmail.com>

pkgname=libksieve-git
pkgver=5.16.42_r1479.gd7035fc3
pkgrel=1
pkgdesc="KDE PIM library for managing sieves"
arch=($CARCH)
url="https://kontact.kde.org"
license=(LGPL)
depends=(kidentitymanagement-git pimcommon-git kmailtransport-git)
makedepends=(git extra-cmake-modules-git boost kdoctools-git)
conflicts=(${pkgname%-git})
provides=(${pkgname%-git})
groups=(kdepim-git)
source=("git+https://github.com/KDE/${pkgname%-git}.git")
sha256sums=('SKIP')

pkgver() {
  cd ${pkgname%-git}
  _ver="$(grep -m1 'set(PIM_VERSION' CMakeLists.txt | cut -d '"' -f2 | tr - .)"
  echo "${_ver}_r$(git rev-list --count HEAD).g$(git rev-parse --short HEAD)"
}

build() {
  cmake -B build -S ${pkgname%-git} \
    -DBUILD_TESTING=OFF
  cmake --build build
}

package() {
  DESTDIR="$pkgdir" cmake --install build
}