summarylogtreecommitdiffstats
path: root/PKGBUILD
blob: 487999a6c8157242fb5ec3f3453b0fe7f7946678 (plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
# Maintainer: Chocobo1 <chocobo1 AT archlinux DOT net>

pkgname=libjcat-git
pkgver=0.1.8.r2.g21976eb
pkgrel=1
pkgdesc="Library for reading and writing Jcat files"
arch=('i686' 'x86_64')
url="https://github.com/hughsie/libjcat"
license=('LGPL')
depends=('glibc' 'gpgme' 'json-glib')
makedepends=('git' 'meson' 'gobject-introspection' 'help2man' 'vala')
provides=('libjcat')
conflicts=('libjcat')
source=("git+https://github.com/hughsie/libjcat.git")
sha256sums=('SKIP')


pkgver() {
  cd "libjcat"

  git describe --long --tags | sed 's/^v//;s/\([^-]*-g\)/r\1/;s/-/./g'
}

build() {
  cd "libjcat"

  meson \
    --buildtype=plain \
    --prefix="/usr" \
    --sbindir="bin" \
    --libexecdir="/usr/lib" \
    "_build"
  meson compile -C "_build"
}

check() {
  cd "libjcat"

  meson test -C "_build"
}

package() {
  cd "libjcat"

  DESTDIR="$pkgdir" meson install -C "_build"
}