summarylogtreecommitdiffstats
path: root/PKGBUILD
blob: e36aae66a184177466f06652f0cb7ba841d1ed5b (plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
# Maintainer: Markus Kalb <mk@filmkreis.tu-darmstadt.de>
# Contributor: Stefan Karner <stefan.karner@student.tuwien.ac.at>
pkgname=libcxml-git
pkgver=0.r124.25e945f
pkgrel=1
pkgdesc="A small C++ library which makes it marginally neater to parse XML using libxml++"
arch=('i686' 'x86_64')
url="http://carlh.net/libcxml"
license=('GPL')
depends=('liblocked-sstream-git' 'libxml++>=2.6' 'boost-libs')
makedepends=('python2' 'pkg-config' 'boost')
provides=('libcxml')
conflicts=('libcxml')
source=("libcxml-git::git+https://github.com/cth103/libcxml.git")
sha256sums=('SKIP')

pkgver() {
    cd libcxml-git
    printf "0.r%s.%s" "$(git rev-list --count HEAD)" "$(git rev-parse --short HEAD)"
}

build() {
    export CXXFLAGS="$CXXFLAGS -std=c++11"
    export PKG_CONFIG_LIBDIR="/usr/lib64/pkgconfig/:/usr/lib/pkgconfig/:$PKG_CONFIG_LIBDIR"
    cd libcxml-git
    python2 waf configure --prefix=/usr
    python2 waf build
}

package() {
    cd libcxml-git
    python2 waf install --destdir=$pkgdir
}