summarylogtreecommitdiffstats
path: root/PKGBUILD
blob: 4272eee01ac9e46729b2113159755a4bce64a6b4 (plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
# Maintainer: Daniel Bertalan <dani@danielbertalan.dev>
# Contributor: Levente Polyak <anthraxx[at]archlinux[dot]org>
# Contributor: Llewelyn Trahaearn <WoefulDerelict at GMail dot com>
# Contributor: FadeMind <fademind at gmail dot com>
# Contributor: Maxime Gauduin <alucryd at archlinux dot org>
# Contributor: bitwave <aur at oomlu dot de>
# Contributor: willemw <willemw12 at gmail dot com>
# Contributor: Balló György <ballogyor+arch at gmail dot com>

_pkgbase=libappindicator
pkgname=${_pkgbase}-sharp
_bzrtag=12.10.0
_bzrrev=296
pkgver=${_bzrtag}.r${_bzrrev}
pkgrel=3
pkgdesc='Allow applications to extend a menu in Unity, KDE or Systray (Mono GTK+ 2 bindings)'
url='https://launchpad.net/libappindicator'
arch=('any')
depends=('mono' "libappindicator-gtk2=${pkgver}" 'gtk-sharp-2' 'glib2')
license=('LGPL2.1' 'LGPL3')
makedepends=('bzr' 'libdbusmenu-gtk2' 'libindicator-gtk2' 'gnome-common' 'dbus-glib' 'perl-xml-libxml' 'gtk-doc' 'python-dulwich')
options=('!strip')
source=(bzr+lp:libappindicator#revision=$_bzrrev
        no-host.patch)
sha512sums=('SKIP'
            'cfc9481ad26712063f9d1bfdd1f94327f579c0c58385cec8adb4e5f12398ef2eb4427a62e6580cda75434d967623235940562f826a909501ee52eef8135703fa')
validpgpkeys=('6FC05581A37D71FCECE165DB5BE41E162CD6358E')  # Charles Kerr <charles.kerr@canonical.com>

prepare() {
  (cd ${_pkgbase}

    # Fall back to tray icon when StatusNotifierHost is not available.
    # https://code.launchpad.net/~muktupavels/libappindicator/no-host/+merge/386817
    patch -p0 < "${srcdir}/no-host.patch"

    sed -i 's/-Werror//' src/Makefile.am
    ./autogen.sh
  )
  cp -ra ${_pkgbase}{,-gtk2}
}

build() {
  export CFLAGS="${CFLAGS} -Wno-deprecated-declarations"
  export CSC='/usr/bin/mcs'

  (cd ${_pkgbase}-gtk2
    ./configure --prefix=/usr \
      --sysconfdir=/etc \
      --localstatedir=/var \
      --with-gtk=2 \
      --disable-{gtk-doc-html,mono-test,static,tests}
    sed -i -e 's/ -shared / -Wl,-O1,--as-needed\0/g' libtool
    make -j1
  )

}

package() {
  cd ${_pkgbase}-gtk2
  make -j1 -C bindings/mono DESTDIR="${pkgdir}" install
}
# vim: ts=2 sw=2 et: