summarylogtreecommitdiffstats
path: root/PKGBUILD
blob: 75fbe194d5229597928fe39e0c5ee973c2160505 (plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
# Maintainer: Lukas Sabota <lukas@lwsabota.com>
# Contributor: Eric BĂ©langer <eric@archlinux.org>

_pkgname=gtk
pkgname=lib32-gtk
pkgver=1.2.10
pkgrel=2
pkgdesc="A multi-platform toolkit (v1) (32-bit)"
arch=('x86_64')
url="http://www.gtk.org/"
license=('LGPL')
depends=('lib32-libxi' 'lib32-glib')
makedepends=('lib32-libxt' 'gcc-multilib' 'glib')
install=gtk.install
source=(https://download.gnome.org/sources/gtk+/1.2/gtk+-${pkgver}.tar.gz
        aclocal-fixes.patch)
sha1sums=('a5adcb909257da01ae4d4761e1d41081d06e4d7c'
          'b034e33efb85d27f3f3fb082c404e3b6ea79259f')

prepare() {
  cd gtk+-${pkgver}
  cp /usr/share/libtool/build-aux/config.guess .
  cp /usr/share/libtool/build-aux/config.sub .
  patch -p0 -i "${srcdir}/aclocal-fixes.patch"
  sed -i "/ac_cpp=/s/\$CPPFLAGS/\$CPPFLAGS -O2/" configure
}

build() {
  export CC="gcc -m32"
  cd gtk+-${pkgver}
  ./configure --prefix=/usr --sysconfdir=/etc \
    --mandir=/usr/share/man --infodir=/usr/share/info \
    --with-xinput=xfree --libdir=/usr/lib32
  make
}

package() {
  cd gtk+-${pkgver}
  make DESTDIR="${pkgdir}" install
  # Cleanup for lib32 package
  rm -rf ${pkgdir}/usr/{include,share,bin}
  rm -rf ${pkgdir}/etc
}