summarylogtreecommitdiffstats
path: root/PKGBUILD
blob: cfce4f46fda26332bfdd9023d3af4be14bc14925 (plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
# Maintainer: Chocobo1 <chocobo1 AT archlinux DOT net>

pkgname=lftp-git
pkgver=4.9.2.r0.g586b2562
pkgrel=2
pkgdesc="Sophisticated file transfer program"
arch=('i686' 'x86_64')
url="https://lftp.yar.ru/"
license=('GPL3')
depends=('expat' 'gnutls' 'hicolor-icon-theme' 'libidn2' 'readline')
makedepends=('git' 'gperf')
optdepends=('perl' 'sh')
provides=('lftp')
conflicts=('lftp')
backup=('etc/lftp.conf')
source=("git+https://github.com/lavv17/lftp.git"
        "autoconf_bump.patch::https://github.com/lavv17/lftp/commit/df0b2b8e4fb3f334114651d9d7b8be5f8e738375.patch")
sha256sums=('SKIP'
            '3838c1964d40fec4a8738513a40e4b593c849dfc0675dd0a45467a14285a3c9c')


prepare() {
  cd "lftp"

  patch -Np1 -i "$srcdir/autoconf_bump.patch"
}

pkgver() {
  cd "lftp"

  git describe --long --tags | sed 's/^v//;s/\([^-]*-g\)/r\1/;s/-/./g'
}

build() {
  cd "lftp"

  ./bootstrap
  ./configure \
    --prefix="/usr" \
    --disable-static
  make -k || true  # ignore errors temporarily
}

check() {
  cd "lftp"

  make check
}

package() {
  cd "lftp"

  make DESTDIR="$pkgdir" install
  rm -rf "$pkgdir/usr/lib"
}