summarylogtreecommitdiffstats
path: root/PKGBUILD
blob: 06b8ae5a916301918f992b6a7076595ecfee8044 (plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
# Maintainer: Lex Childs <lexchilds@gmail.com>
pkgname=leftwm-git
pkgver=0.2.7.r21.g3f30650
pkgrel=2
epoch=2
pkgdesc="Leftwm - A tiling window manager for the adventurer"
arch=('i686' 'x86_64')
url="https://github.com/leftwm/leftwm"
license=('MIT')
makedepends=('cargo' 'git')
optdepends=('dmenu: default launcher'
            'feh: used to set background images'
            'lemonbar: light weight bar'
            'polybar: light weight bar')
provides=('leftwm')
conflicts=('leftwm')
source=("${pkgname}::git+https://github.com/leftwm/leftwm.git")
md5sums=('SKIP')

build() {
  cd $pkgname
  cargo build --release
}

pkgver() {
  cd $pkgname
  git describe --tags | sed 's+-+.r+' | tr - . 
}

package() {
  cd $pkgname/target/release
  install -Dm755 leftwm leftwm-worker leftwm-state leftwm-check leftwm-command -t "$pkgdir"/usr/bin

  install -d "$pkgdir"/usr/share/leftwm
  cp -R "$srcdir"/$pkgname/themes "$pkgdir"/usr/share/leftwm

  install -Dm644 "$srcdir"/$pkgname/leftwm.desktop "$pkgdir"/usr/share/xsessions/leftwm.desktop
}