summarylogtreecommitdiffstats
path: root/PKGBUILD
blob: 157b43e8713bc4d3a35112c4af57a6dc5efb1bb9 (plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
# Maintainer: WoefulDerelict <WoefulDerelict at GMail dot com>
# Contributor: speps <speps at aur dot archlinux dot org>

pkgname=laditools-git
pkgver=1.1.0.r10.g2946670
pkgrel=1
pkgdesc="Utilities to improve integration and workflow with JACK and LASH."
arch=('any')
url="https://github.com/LADI/laditools"
license=('GPL3')
depends=('glade' 'jack' 'pygtk' 'python2' 'python2-enum34' 'python2-yaml')
makedepends=('git' 'python2-distutils-extra')
provides=("${pkgname%-*}")
conflicts=("${pkgname%-*}")
source=("${pkgname%-*}::git+https://github.com/alessio/laditools.git")
sha512sums=('SKIP')
_branch=master

prepare() {
  cd "${pkgname%-*}"
  git checkout ${_branch}
}

pkgver() {
  cd "${pkgname%-*}"
  ( set -o pipefail
    git describe --long --tags 2>/dev/null | sed 's/^v//;s/\([^-]*-g\)/r\1/;s/-/./g' ||
    printf "r%s.%s" "$(git rev-list --count HEAD)" "$(git rev-parse --short HEAD)"
  )
}

build() {
  cd "${pkgname%-*}"
  python2 setup.py build
}

package() {
  cd "${pkgname%-*}"
  python2 setup.py install --prefix=/usr --root="${pkgdir}/"
}