summarylogtreecommitdiffstats
path: root/PKGBUILD
blob: 2636010f3830e33aee748d97577a6481c33d641f (plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
# Maintainer: Christian Muehlhaeuser <muesli@gmail.com>
pkgname=kristall-git
pkgver=r506.c8eae06
pkgrel=1
pkgdesc="A high-quality visual cross-platform gemini browser."
arch=('x86_64')
url="https://github.com/MasterQ32/kristall"
license=('GPL3')
makedepends=('qt5-tools')
depends=('qt5-base' 'qt5-multimedia' 'openssl' 'qt5-svg')
provides=("kristall")
conflicts=("kristall")
source=($pkgname::git://github.com/MasterQ32/kristall.git)
sha256sums=('SKIP')

pkgver() {
    cd "$srcdir/$pkgname"
    printf "r%s.%s" "$(git rev-list --count HEAD)" "$(git rev-parse --short HEAD)"
}

prepare() {
  # Fix desktop launcher icon name (allow per-theme override)
  sed -i 's/net.random-projects.//' "$srcdir/$pkgname"/Kristall.desktop
}

build() {
  cd "$srcdir/$pkgname"
  make
}

package() {
  cd "$srcdir/$pkgname"

  install -D build/kristall "$pkgdir/usr/bin/kristall"
  install -D LICENSE "$pkgdir/usr/share/licenses/kristall/LICENSE"
  install -Dm644 Kristall.desktop "$pkgdir/usr/share/applications/kristall.desktop"
  install -D kristall-mime-info.xml "$pkgdir/usr/share/mime/packages/kristall-mime-info.xml"

  for size in 16 32 64 128; do
    install -Dm644 src/icons/kristall-$size.png "$pkgdir/usr/share/icons/hicolor/${size}x${size}/apps/kristall.png"
  done
  install -Dm644 src/icons/kristall.svg "$pkgdir/usr/share/icons/hicolor/scalable/apps/kristall.svg"
}