summarylogtreecommitdiffstats
path: root/PKGBUILD
blob: f31a49192c87e05cf66198722edf2533842eef3f (plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
# Maintainer: rhssk <rssk@protonmail.com>
pkgname='kicost-git'
_gitname='kicost'
pkgver=r915.72c887d
pkgrel=1
pkgdesc="Build cost spreadsheet for a KiCad project"
url="https://xesscorp.github.io/KiCost"
depends=(
    'python'
    'python-setuptools'
    'python-beautifulsoup4'
    'python-xlsxwriter'
    'python-future'
    'python-lxml'
    'python-yattag'
    'python-tqdm'
    'python-currencyconverter'
    'python-pycountry'
    'python-requests'
)
makedepends=('git')
provides=("${_gitname}")
conflicts=("${_gitname}")
license=('MIT')
arch=('any')
source=('git+https://github.com/xesscorp/kicost.git')
sha256sums=('SKIP')

pkgver() {
    cd "$_gitname"

    printf "r%s.%s" "$(git rev-list --count HEAD)" "$(git rev-parse --short HEAD)"
}

check() {
    cd "$_gitname"

    python -m unittest tests.test_kicost
}

package() {
    cd "$_gitname"

    python setup.py install --root="$pkgdir" --optimize=1
}