summarylogtreecommitdiffstats
path: root/PKGBUILD
blob: 3264f73ece05433244bd60ced47d0429a330f137 (plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
# Merged with official ABS khtml PKGBUILD by João, 2021/02/01 (all respective contributors apply herein)
# Maintainer: João Figueiredo <jf.mundox@gmail.com>
# Contributor: Andrea Scarpino <andrea@archlinux.org>

pkgname=khtml-git
pkgver=5.79.0_r528.gfb3c9ef
pkgrel=1
pkgdesc='KHTML APIs'
arch=($CARCH)
url='https://community.kde.org/Frameworks'
license=(LGPL)
depends=(giflib kparts-git kjs-git phonon-qt5)
makedepends=(git extra-cmake-modules-git gperf)
conflicts=(${pkgname%-git})
provides=(${pkgname%-git})
groups=(kf5-aids-git)
source=("git+https://github.com/KDE/${pkgname%-git}.git")
sha256sums=('SKIP')

pkgver() {
  cd ${pkgname%-git}
  _ver="$(grep -m1 "set(KF5\?_VERSION" CMakeLists.txt | cut -d '"' -f2 | tr - .)"
  echo "${_ver}_r$(git rev-list --count HEAD).g$(git rev-parse --short HEAD)"
}

build() {
  cmake -B build -S ${pkgname%-git} \
    -DBUILD_TESTING=OFF
  cmake --build build
}

package() {
  DESTDIR="$pkgdir" cmake --install build
}