summarylogtreecommitdiffstats
path: root/PKGBUILD
blob: 07bb783ab05622d4b57b610ab14ce5be73ae4b22 (plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
# Maintainer: Gustavo Castro < gustawho [ at ] gmail [ dot ] com >

pkgname=kclock-git
pkgver=r157.e96a786
pkgrel=1
pkgdesc="Clock app for Plasma Mobile"
arch=(x86_64)
url="https://invent.kde.org/plasma-mobile/kclock"
license=(GPL3)
depends=(ki18n kconfig kcoreaddons knotifications kdbusaddons kirigami2 kirigami-addons-git)
makedepends=(git cmake extra-cmake-modules)
provides=(kclock)
conflicts=(kclock)
source=("git+https://invent.kde.org/plasma-mobile/kclock.git")
sha256sums=('SKIP')

pkgver() {
  cd "${pkgname%-git}"
  ( set -o pipefail
    git describe --long 2>/dev/null | sed 's/\([^-]*-g\)/r\1/;s/-/./g' ||
    printf "r%s.%s" "$(git rev-list --count HEAD)" "$(git rev-parse --short HEAD)"
  )
}

prepare() {
  cd "${pkgname%-git}"
  install -d build
}

build() {
  cd "${pkgname%-git}/build"
  cmake ..
  make
}

package() {
  cd "${pkgname%-git}/build"
  make DESTDIR="$pkgdir" install
}