summarylogtreecommitdiffstats
path: root/PKGBUILD
blob: 8045d3b6656707a7bba276ef45aaed819bda8177 (plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
# Maintainer: Chocobo1 <chocobo1 AT archlinux DOT net>

pkgname=jsoncpp-git
pkgver=1.8.4.r139.g5b91551
pkgrel=1
pkgdesc="C++ library for interacting with JSON"
arch=('i686' 'x86_64')
url="https://github.com/open-source-parsers/jsoncpp"
license=('MIT' 'custom')
depends=('gcc-libs')
makedepends=('git' 'meson' 'python')
provides=('jsoncpp')
conflicts=('jsoncpp')
options=('staticlibs')
source=("git+https://github.com/open-source-parsers/jsoncpp.git")
sha256sums=('SKIP')


pkgver() {
  cd "jsoncpp"

  git describe --long --tags | sed 's/^v//;s/\([^-]*-g\)/r\1/;s/-/./g'
}

build() {
  cd "jsoncpp"

  meson \
    --buildtype=plain \
    --prefix="/usr" \
    --sbindir="bin" \
    --default-library both \
    "_build"
  ninja -C "_build"
}

check() {
  cd "jsoncpp"

  meson test -C "_build"

  cd "test"
  python "runjsontests.py" ../_build/jsontestrunner
  python "rununittests.py" ../_build/jsoncpp_test
}

package() {
  cd "jsoncpp"

  DESTDIR="$pkgdir" meson install -C "_build"
  install -Dm644 "LICENSE" -t "$pkgdir/usr/share/licenses/jsoncpp"
}