summarylogtreecommitdiffstats
path: root/PKGBUILD
blob: bf1f2b7d9e04e3990af0043724ad210351a22985 (plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
# Maintainer: Vianney le Clément <vleclement AT gmail·com>
_pkgname=jbig2enc
pkgname=$_pkgname-git
pkgver=0.29
pkgrel=1
pkgdesc="A JBIG2 image encoder"
arch=('i686' 'x86_64')
url="https://github.com/agl/jbig2enc"
license=('Apache')
depends=('gcc-libs' 'leptonica>=1.68' 'libpng' 'libjpeg' 'libtiff')
optdepends=('python2: for pdf.py')
provides=('jbig2enc')
conflicts=('jbig2enc')
makedepends=('git')
source=("git://github.com/agl/$_pkgname.git")
md5sums=('SKIP')

pkgver() {
  cd "$srcdir/$_pkgname"
  git describe --tags | sed 's/-/./g'
}

prepare() {
  cd "$srcdir/$_pkgname"
  sed -i 's@^#!/usr/bin/python$@#!/usr/bin/env python2@' pdf.py
}

build() {
  cd "$srcdir/$_pkgname"
  ./autogen.sh
  ./configure --prefix=/usr
  make
}

package() {
  cd "$srcdir/$_pkgname"
  make install DESTDIR="$pkgdir"
}