summarylogtreecommitdiffstats
path: root/PKGBUILD
blob: 811844b31cdaa477692ec0c7d9136846c5d298b5 (plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
# Maintainer: Christopher Arndt <aur -at- chrisarndt -dot- de>

_pkgname=jack_mixer
pkgname="${_pkgname}-git"
pkgver=13.r355.618dbed
pkgrel=1
pkgdesc="A GTK based Jack audio mixer (git version)"
arch=('x86_64')
url="https://rdio.space/jackmixer/"
license=('GPL2')
groups=('pro-audio')
depends=('gcc-libs' 'hicolor-icon-theme' 'python-cairo' 'python-gobject' 'python-pyxdg')
makedepends=('git' 'glib2' 'jack')
optdepends=('new-session-manager: NSM session management support')
provides=("${_pkgname}")
conflicts=("${_pkgname}")
source=("${_pkgname}::git+https://github.com/jack-mixer/jack_mixer.git")
sha256sums=('SKIP')

pkgver() {
  cd "${srcdir}/${_pkgname}"
  local ver="$(grep '^AC_INIT' configure.ac | sed -E 's/.*, ([0-9]+)\)$/\1/')"
  echo "$ver.r$(git rev-list --count HEAD).$(git rev-parse --short HEAD)"
}

build() {
  cd "${srcdir}/${_pkgname}"
  ./autogen.sh --prefix=/usr
  make
}

package() {
  depends+=('libglib-2.0.so' 'libjack.so')
  cd "${srcdir}/${_pkgname}"
  make DESTDIR="${pkgdir}" install
  # Install documentation
  install -Dm644 AUTHORS README.md NEWS -t "${pkgdir}/usr/share/doc/${pkgname}"
}