summarylogtreecommitdiffstats
path: root/PKGBUILD
blob: 2eb3d5974db8867ab5c4f6e77bbc51ecc54ba123 (plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
# Maintainer: Ivan Shapovalov <intelfx@intelfx.name>
# Contributor: Matthew Bauer <mjbauer95@gmail.com>

pkgname=idevicerestore-git
epoch=1
pkgver=r663.0b4810f
pkgrel=1
pkgdesc="Restore/upgrade firmware of iOS devices"
arch=('i686' 'x86_64')
url="http://www.libimobiledevice.org"
license=('LGPL3')
depends=('libirecovery-git' 'libimobiledevice-git' 'libzip' 'openssl' 'curl')
makedepends=('git')
source=("git+https://github.com/libimobiledevice/idevicerestore"
        "0001-configure.ac-check-for-pthreads.patch")
sha256sums=('SKIP'
            'c259a9f977de42fbfde75ad0c9a4d813b7d39bf217ee416902409403cd6d7931')

pkgver() {
	cd idevicerestore
	printf "r%s.%s" "$(git rev-list --count HEAD)" "$(git rev-parse --short HEAD)"
}

prepare() {
	cd idevicerestore
	for p in "${srcdir}"/*.patch; do
		patch -Np1 -i "${p}"
	done
	NOCONFIGURE=1 ./autogen.sh
}

build() {
	cd idevicerestore
	./configure --prefix=/usr
	make
}

package() {
	cd idevicerestore
	make DESTDIR="$pkgdir" install
}