summarylogtreecommitdiffstats
path: root/PKGBUILD
blob: c985a804cc055d92fe78e1052a5e2216cf6ba66b (plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
# Maintainer: Chocobo1 <chocobo1 AT archlinux DOT net>

pkgname=httperf-git
pkgver=cc88843
pkgrel=2
epoch=1
pkgdesc="The HTTP load generator"
arch=('i686' 'x86_64')
url="https://github.com/httperf/httperf"
license=('GPL')
makedepends=('git' 'openssl-1.0')
provides=('httperf')
conflicts=('httperf')
source=("git+https://github.com/httperf/httperf.git"
        "openssl-1.0.patch")
sha256sums=('SKIP'
            '14e17f66425dc8433255b6ba893e933dce3fabb37e860290f4cfaf3a24c36ac0')


pkgver() {
    cd "httperf"

    git describe --long --tags --always | sed 's/\([^-]*-g\)/r\1/;s/-/./g'
}

prepare() {
    cd "httperf"

    patch -Np1 -i "../openssl-1.0.patch"

    autoreconf -i
    mkdir -p "build"
}

build() {
    cd "httperf/build"

    ../configure --prefix=/usr
    make
}

package() {
    cd "httperf/build"

    make DESTDIR="$pkgdir" install
}