summarylogtreecommitdiffstats
path: root/PKGBUILD
blob: 41a7b969bccfc3a36f8d240f79d5c18c4965cd30 (plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
# Contributor: Dongsheng Cai <imdongsheng@gmail.com>
# Maintainer: Adria Arrufat (swiftscythe) <swiftscythe@gmail.com>

_pkgname=gthumb
pkgname=gthumb-git
pkgver=3.7.1+24+g8765cb91
pkgrel=1
pkgdesc="Image browser and viewer for the GNOME Desktop"
arch=(i686 x86_64)
url="http://live.gnome.org/gthumb/"
license=('GPL')
provides=($_pkgname=$pkgver)
conflicts=($_pkgname)
depends=(desktop-file-utils hicolor-icon-theme dconf librsvg clutter-gtk
         gst-plugins-base-libs gsettings-desktop-schemas libwebp
         webkit2gtk)
makedepends=(intltool libchamplain libraw exiv2 itstool brasero librsvg
             libraw liboauth docbook-xsl gnome-common yelp-tools)
optdepends=('libraw: read RAW files'
            'exiv2: metadata support'
            'libchamplain: map viewer'
            'brasero: burn discs'
            'liboauth: web albums')
options=('!emptydirs')
source=("git+https://gitlab.gnome.org/GNOME/gthumb.git")
md5sums=('SKIP')

pkgver() {
  cd $_pkgname/
  git describe --tags | sed 's/_/./g;s/-/+/g'
}

build() {
  arch-meson $_pkgname build \
    --buildtype debugoptimized \
    -D libchamplain=true
  ninja -C build
}

package() {
  DESTDIR="$pkgdir" meson install -C build
}