summarylogtreecommitdiffstats
path: root/PKGBUILD
blob: 55e294fe797b38a48b7e461e613197cf31de30a1 (plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
# Maintainer: Philip Goto <philip.goto@gmail.com>
# Contributor: Alad Wenter <alad@mailbox.org>
# Contributor: Martin Wimpress <code@flexion.org>

pkgname=gpick-git
pkgver=0.2.6rc1.r84.gebee8a0
pkgrel=1
pkgdesc="Advanced color picker written in C++ using GTK+ toolkit"
arch=(i686 x86_64 armv7h aarch64)
url="http://www.gpick.org/"
license=(BSD)
depends=(boost-libs gtk3 lua)
makedepends=(boost cmake ragel)
provides=(gpick)
conflicts=(gpick)
source=("git+https://github.com/thezbyg/gpick.git")
sha256sums=(SKIP)

pkgver() {
    cd gpick
    git describe --long --tags | sed 's/^gpick-//;s/\([^-]*-g\)/r\1/;s/-/./g'
}

build() {
    mkdir build
    cd build
    cmake ../gpick -DCMAKE_INSTALL_PREFIX="/usr/"
    make
}

package() {
    cd build
    make DESTDIR="${pkgdir}/" install
    install -Dm644 "../gpick/LICENSE.txt" "${pkgdir}/usr/share/licenses/${pkgname}/LICENSE"
}