summarylogtreecommitdiffstats
path: root/PKGBUILD
blob: e5118ce4ca002f014a3948a83807f2a757931991 (plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
# Maintainer: Dimitris Kiziridis <ragouel at outlook dot com>

pkgname=go-dsp-guitar-bin
pkgver=1.6.1
pkgrel=2
pkgdesc="A cross-platform multichannel multi-effects processor for electric guitars and other instruments"
arch=('x86_64')
url='https://github.com/andrepxx/go-dsp-guitar'
license=('Apache')
provides=('go-dsp-guitar' 'dsp-guitar')
conflicts=('go-dsp-guitar' 'dsp-guitar' 'go-dsp-guitar-git')
depends=('jack')
makedepends=('openssl')
source=("${pkgname}-${pkgver}.tar.gz::https://github.com/andrepxx/go-dsp-guitar/releases/download/v${pkgver}/go-dsp-guitar-v${pkgver}.tar.gz")
sha256sums=('a1bb02f5fe85d32a19422f1fac4c0aaa9019a7adff49a6e776d30ed774a286c3')

prepare() {
  cd "${pkgname%-bin}"
  rm -rf keys
  mkdir -p keys
  openssl genrsa -out keys/private.pem 4096
  openssl req -new -x509 -days 365 -sha512 -key keys/private.pem -out keys/public.pem -subj "/C=DE/ST=Berlin/L=Berlin/O=None/OU=None/CN=localhost"
}

package() {
  cd "${pkgname%-bin}"
  install -Dm755 dsp-linux-amd64 "${pkgdir}/opt/${pkgname%-bin}/go-dsp-guitar"
  cp -R config "${pkgdir}/opt/${pkgname%-bin}/"
  cp -R ir "${pkgdir}/opt/${pkgname%-bin}/"
  cp -R keys "${pkgdir}/opt/${pkgname%-bin}/"
  cp -R webroot "${pkgdir}/opt/${pkgname%-bin}/"
  install -d "${pkgdir}/usr/bin/"
  ln -s /opt/${pkgname%-bin}/${pkgname%-bin} "${pkgdir}/usr/bin/${pkgname%-bin}"
  chmod o+r "${pkgdir}/opt/go-dsp-guitar/keys/private.pem"
}