summarylogtreecommitdiffstats
path: root/PKGBUILD
blob: 3678aff8f92daf6d215ea57f57a46ceb9c6160d2 (plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
# Maintainer: Jonas Witschel <diabonas@archlinux.org>
pkgname=gnu-efi-libs-fedora-git
pkgver=r237.4eaf7e1
pkgrel=1
pkgdesc='Library for building UEFI Applications using GNU toolchain (Fedora development version)'
arch=('x86_64')
url='https://sourceforge.net/projects/gnu-efi/'
license=('BSD')
makedepends=('git')
provides=("${pkgname%-fedora-git}")
conflicts=("${pkgname%-fedora-git}")
source=("git+https://github.com/vathpela/gnu-efi.git#branch=fedora-32")
sha512sums=('SKIP')

pkgver() {
	cd "${pkgname%-libs-fedora-git}"
	printf 'r%s.%s' "$(git rev-list --count HEAD)" "$(git rev-parse --short HEAD)"
}

build() {
	cd "${pkgname%-libs-fedora-git}"
	make
	LDFLAGS='' make apps
}

package() {
	cd "${pkgname%-libs-fedora-git}"
	make INSTALLROOT="$pkgdir" PREFIX=/usr install
	install -Dm644 "$srcdir/${pkgname%-libs-fedora-git}/x64/apps"/*.efi -t "$pkgdir/usr/share/gnu-efi/apps/x64"
	install -Dm644 "$srcdir/${pkgname%-libs-fedora-git}/README.efilib" "$pkgdir/usr/share/licenses/$pkgname/LICENSE"
}