summarylogtreecommitdiffstats
path: root/PKGBUILD
blob: 53bfd532e77f0597d9383dee1a8e882bf2ac1867 (plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
# Maintainer: Mark Wagie <mark dot wagie at tutanota dot com>
pkgname=gnome-web-shortcuts-extension-git
pkgver=r16.2d89c1e
pkgrel=2
pkgdesc="Adds a 'Create web link...' menu item to Nautilus, which makes it simple to
         create URL shortcut files in directories"
arch=('any')
url="https://gitlab.gnome.org/sthursfield/gnome-web-shortcuts-extension"
license=('unknown')
depends=('nautilus' 'firefox')
makedepends=('git' 'meson')
provides=("${pkgname%-git}")
conflicts=("${pkgname%-git}")
install="${pkgname%-git}.install"
source=("git+https://gitlab.gnome.org/sthursfield/gnome-web-shortcuts-extension.git")
sha256sums=('SKIP')

pkgver() {
	cd "${pkgname%-git}"
 	printf "r%s.%s" "$(git rev-list --count HEAD)" "$(git rev-parse --short HEAD)"
}

build() {
	arch-meson "${pkgname%-git}" build
	meson compile -C build
}

# No tests defined
#check() {
#	meson test -C build
#}

package() {
	DESTDIR="$pkgdir" meson install -C build
}