summarylogtreecommitdiffstats
path: root/PKGBUILD
blob: e9633576bedd386343a9c71c2fb9dc0bca1af336 (plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
pkgname=gnome-settings-daemon-git
_pkgname=gnome-settings-daemon
pkgver=3.33.90+62+g7bf807de
pkgrel=1
pkgdesc="GNOME Settings Daemon"
url="https://gitlab.gnome.org/GNOME/gnome-settings-daemon"
arch=(x86_64)
license=(GPL)
depends=('dconf' 'gnome-desktop' 'gsettings-desktop-schemas' 'libcanberra-pulse' 'libnotify' 'systemd-libs' 'libwacom' 'pulseaudio' 'pulseaudio-alsa' 'upower' 'librsvg' 'libgweather' 'geocode-glib' 'geoclue2' 'nss' 'libgudev' 'gtk3-print-backends' 'libnm' 'gcr')
makedepends=('xf86-input-wacom' 'libxslt' 'docbook-xsl' 'python' 'git' 'meson')
checkdepends=('python-gobject' 'python-dbusmock')
provides=('gnome-settings-daemon')
conflicts=('gnome-settings-daemon')
source=("git+https://gitlab.gnome.org/GNOME/gnome-settings-daemon.git"
        "git+https://gitlab.gnome.org/GNOME/libgnome-volume-control.git")
sha256sums=('SKIP'
            'SKIP')

pkgver() {
  cd $_pkgname
  git describe --tags | sed 's/^GNOME_SETTINGS_DAEMON_//;s/_/./g;s/-/+/g'
}

prepare() {
  cd $_pkgname

  git submodule init
  git config --local submodule.subprojects/gvc.url "$srcdir/libgnome-volume-control"
  git submodule update
}

build() {
  arch-meson $_pkgname build
  ninja -C build
}

package() {
  DESTDIR="$pkgdir" meson install -C build
}