summarylogtreecommitdiffstats
path: root/PKGBUILD
blob: 95a6a9769f65a64a38795a08fc508cd675217d2e (plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
# Maintainer: Chocobo1 <chocobo1 AT archlinux DOT net>

pkgname=giflib-git
pkgver=5.2.1.r2.gadf5a1a
pkgrel=1
pkgdesc="A library and utilities for processing GIFs"
arch=('i686' 'x86_64')
url="http://giflib.sourceforge.net/"
license=('MIT')
depends=('glibc')
makedepends=('git' 'docbook-xml' 'docbook-xsl' 'xmlto')
provides=('giflib' 'libgif.so')
conflicts=('giflib')
options=('staticlibs')
source=("git+https://git.code.sf.net/p/giflib/code")
sha256sums=('SKIP')


pkgver() {
  cd "code"

  git describe --long --tags | sed 's/^v//;s/\([^-]*-g\)/r\1/;s/-/./g'
}

build() {
  cd "code"

  make
}

check() {
  cd "code"

  make check
}

package() {
  cd "code"

  make \
    PREFIX="/usr" \
    DESTDIR="$pkgdir" \
    install
  install -Dm644 "COPYING" -t "$pkgdir/usr/share/licenses/giflib"
}