summarylogtreecommitdiffstats
path: root/PKGBUILD
blob: 4de38e3fd6f97eb31e1377ad29c86709b6067318 (plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
# Maintainer: ntruessel <nicolas+arch@ntruessel.ch>
# Contributor: Domenico Iezzi <domenico.iezzi.201@gmail.com>

pkgname=eiffelstudio-bin
_major=19
_minor=05
_build=103187
pkgver=${_major}.${_minor}.${_build}
pkgrel=2
pkgdesc="IDE for the Eiffel programming language (opensource edition)"
arch=("x86_64")
url="https://www.eiffel.org/downloads"
license=("GPL")
depends=("gtk2" "libxtst" "gcc")
provides=("eiffelstudio")
conflicts=("eiffelstudio")
options=("staticlibs")
source=("eiffel-studio.profile"
        "https://downloads.sourceforge.net/project/eiffelstudio/EiffelStudio%20${_major}.${_minor}/Build_${_build}/Eiffel_${_major}.${_minor}_gpl_${_build}-linux-x86-64.tar.bz2"
        "eiffel-studio.desktop")
sha256sums=('3660f50b6900cecc22e79913d502a641a3355b9353bdf4b97185e6be100bb59a'
            'd2cf46dbf20fdcf3b1fcd27acb6ac5457dcc8d3de51613663ede8a4adf7f383e'
            'bee49bd0a0fc335e32881918ff5374e4b1b9ecac32f72943f0256ee26e80345f')

prepare() {
	# remove windows files and folders
	find "${srcdir}/Eiffel_${_major}.${_minor}" -name "msc*" -type d -exec rm -rf {} +
	find "${srcdir}/Eiffel_${_major}.${_minor}" -name "*.dll" -type f -exec rm -rf {} +
}

package() {
	install -dm755 "${pkgdir}/opt"
	cp -a "${srcdir}/Eiffel_${_major}.${_minor}/" "${pkgdir}/opt/eiffel-studio"

	sed -i 's/@ARCH@/linux-x86-64/g' "${srcdir}/eiffel-studio.profile"

	install -Dm755 "${srcdir}/eiffel-studio.profile" "${pkgdir}/etc/profile.d/eiffel-studio.sh"
	install -Dm644 "${srcdir}/Eiffel_${_major}.${_minor}/studio/bitmaps/png/estudio.png" "${pkgdir}/usr/share/icons/hicolor/48x48/apps/eiffel-studio.png"
	install -Dm644 "${srcdir}/eiffel-studio.desktop" "${pkgdir}/usr/share/applications/eiffel-studio.desktop"
}