summarylogtreecommitdiffstats
path: root/PKGBUILD
blob: bdd4f04a8ef55309671b93997e225b3309226c5d (plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
# Maintainer: Andrew Rabert <draje@nullsum.net>

_pkgname=Doom64EX
pkgname=doom64ex-git
pkgver=r261.c2619d1
pkgrel=2
pkgdesc="Doom64EX is a reverse-engineering project aimed to recreate Doom64 as close as possible with additional modding features."
arch=('i686' 'x86_64')
url="https://github.com/svkaiser/Doom64EX"
license=('GPL2')
depends=('fluidsynth' 'libpng' 'sdl2' 'sdl2_net' 'zlib')
makedepends=('cmake' 'git')
source=("git+$url")
sha256sums=('SKIP')

pkgver() {
  cd "${srcdir}/${_pkgname}"

  printf "r%s.%s" "$(git rev-list --count HEAD)" "$(git rev-parse --short HEAD)"
}

build() {
  cd "${srcdir}/${_pkgname}"

  cmake . -DCMAKE_INSTALL_PREFIX=/usr \
          -DENABLE_SYSTEM_FLUIDSYNTH=ON
  make
}

package() {
  cd "${srcdir}/${_pkgname}"

  make DESTDIR="$pkgdir" libdir="$pkgdir/usr/lib" install
}