summarylogtreecommitdiffstats
path: root/PKGBUILD
blob: fc980c96418466521fbb07196db7a8c39e978103 (plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
# Maintainer: Pellegrino Prevete <pellegrinoprevete@gmail.com>
# Contributor: Balló György <ballogyor+arch at gmail dot com>

_pkgname=deja-dup
pkgname=$_pkgname-git
pkgver=42.4+142+g39e801e8
pkgrel=2
pkgdesc="Simple backup tool, that hides the complexity of backing up the Right Way and uses duplicity as the backend"
arch=('any')
url="https://wiki.gnome.org/Apps/DejaDup"
license=(GPL)
depends=(duplicity gvfs libadwaita libsecret org.freedesktop.secrets python-gobject python-pydrive)
makedepends=(appstream-glib itstool meson vala)
source=("git+https://gitlab.gnome.org/World/$_pkgname")
conflicts=("deja-dup")
provides=("deja-dup")
validpgpkeys=('A3A5C2FC56AE7341D308D8571B50ECA373F3F233') # Michael Terry
sha512sums=('SKIP')

pkgver() {
  cd $_pkgname
  git describe --tags | sed 's/-/+/g'
}

build() {
  arch-meson -Denable_nautilus=true $_pkgname build
  meson compile -C build
}

check() {
  meson test -C build
}

package() {
  DESTDIR="$pkgdir" meson install -C build
}