summarylogtreecommitdiffstats
path: root/PKGBUILD
blob: 28cef447bba580825044af46178c67e355a8c232 (plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
# Maintainer: Deposite Pirate <dpirate at metalpunks dot info>
#
# Upstream: https://git.metalpunks.info/arch-ports

_pkgname=ddb_medialib
pkgname=deadbeef-plugin-medialib-git
pkgver=r102.ga9ae3c4
pkgrel=1
pkgdesc="DeaDBeeF media library plugin"
arch=('i686' 'x86_64')
url="https://github.com/sgomin/ddb_medialib"
license=('custom')
depends=('deadbeef' 'gtkmm3' 'boost')
makedepends=('git')
source=("${_pkgname}::git+https://github.com/sgomin/${_pkgname}"
        "${_pkgname}-makefile.patch")
sha256sums=('SKIP'
            '38db1362fd3d6117b98b36499f508ac55bf9017f2068ad8cde38bd201f24133e')

pkgver() {
  cd "${_pkgname}"
  printf "r%s.g%s" \
    "$(git rev-list --count HEAD)" \
    "$(git rev-parse --short HEAD)"
}

prepare() {
  cd "${_pkgname}"

  # Arch compile FLAGS
  patch -p1 -i ../${_pkgname}-makefile.patch
}

build() {
  cd "${_pkgname}"
  make COPT="${CFLAGS}" CXXOPT="${CXXFLAGS}"
}

package() {
  cd "${_pkgname}"
  make DESTDIR="${pkgdir}" install
}