summarylogtreecommitdiffstats
path: root/PKGBUILD
blob: f336801eadc51e2e24fbfdad9821ce2ae9803580 (plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
# Maintainer: Mark Wagie <mark dot wagie at tutantota dot com>
# Contributor: Federico Di Pierro <nierro92@gmail.com>
pkgname=clightd
pkgver=5.2
pkgrel=3
pkgdesc="Bus interface to change screen brightness and capture frames from webcam."
arch=('i686' 'x86_64' 'aarch64')
url="https://github.com/FedeDP/Clightd"
license=('GPL')
depends=('systemd-libs>=237' 'linux-api-headers' 'libx11' 'libxrandr' 'libxext' 'polkit'
         'ddcutil>=0.9.5' 'libmodule>=5.0.0' 'libjpeg-turbo' 'libusb' 'libdrm' 'wayland')
makedepends=('git' 'cmake')
source=("$pkgname-$pkgver.tar.gz::$url/archive/$pkgver.tar.gz")
sha256sums=('6636d58eae7aff4780534258940d1f680637fc1b983320e15aa2fd5be8648853')

build() {
	cmake -B build -S Clightd-$pkgver \
		-G "Unix Makefiles" \
		-DCMAKE_BUILD_TYPE=None \
		-DCMAKE_INSTALL_PREFIX=/usr \
		-DCMAKE_INSTALL_LIBEXECDIR=lib/"$pkgname" \
		-DENABLE_DDC=1 \
		-DENABLE_GAMMA=1 \
		-DENABLE_DPMS=1 \
		-DENABLE_SCREEN=1 \
		-DENABLE_YOCTOLIGHT=1 \
		-Wno-dev
	make -C build
}

package() {
	make -C build DESTDIR="$pkgdir" install
}