summarylogtreecommitdiffstats
path: root/PKGBUILD
blob: b792db9acb766fd80b8853041f3faa28a32b8bb9 (plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
# Maintainer: cocreature <moritz.kiefer<at>purelyfunctional<dot>org>

pkgname=carla-git
pkgver=1.9.6.r500.g0e81fd3
pkgrel=1
pkgdesc="Audio Plugin Host"
arch=('i686' 'x86_64')
url="http://kxstudio.sf.net/carla"
license=('GPL2')
conflicts=('carla')
provides=('carla')
depends=("python-pyqt4"
         "clthreads"
         "fluidsynth"
         "gtk2"
         "gtk3"
         "liblo"
         "linuxsampler-svn"
         "mxml"
         "zita-convolver"
         "zita-resampler"
         "clxclient"
         "ntk-git"
         "qt5-base")
makedepends=('git')
optdepends=("pygtk: NekoFilter UI"
            "zlib: extra native plugins"
            "zynaddsubfx-git: zynaddsubfx banks")
source=("$pkgname"::'git://github.com/falkTX/Carla.git')
md5sums=('SKIP')
install="$pkgname.install"

pkgver() {
  cd "$srcdir/$pkgname"
  git describe --long --tags | sed 's/\([^-]*-g\)/r\1/;s/-/./g'
}

prepare() {
  cd "$srcdir/$pkgname"
  sed 's/libpng12/libpng/' -i "source/Makefile.mk"
  sed 's/libpng12/libpng/' -i "source/native-plugins/Makefile"
}

build() {
  cd "$srcdir/$pkgname"
  make EXPERIMENTAL_PLUGINS=true
}

package() {
  cd "$srcdir/$pkgname"
  make EXPERIMENTAL_PLUGINS=true DESTDIR="$pkgdir/" PREFIX=/usr install
}