summarylogtreecommitdiffstats
path: root/PKGBUILD
blob: 97a5ae4db3c1ce63dfe473e4f773d89eda558464 (plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
# Maintainer: wordofglass <wordofglass@users.noreply.github.com>

pkgname=beets-copyartifacts-git
pkgver=0.1.2.r34.1a0c281
pkgrel=1
epoch=1 # had the versioning messed up initially...
pkgdesc="A beets plugin that moves non-music files during the import process."
arch=('any')
url="https://github.com/sbarakat/${pkgname%-git}"
license=('MIT')
depends=('python' 'beets')
makedepends=('git')
provides=("${pkgname%-git}")
conflicts=("${pkgname%-git}")
source=("git+${url}.git")
md5sums=('SKIP')

pkgver() {
    cd "$srcdir/${pkgname%-git}"
    printf "%s" "$(git describe --long | sed 's/^v//;s/\([^-]*-\)g/r\1/;s/-/./g')"
}

package() {
    cd "$srcdir/${pkgname%-git}"
    python setup.py install --root="$pkgdir/" --optimize=1
    install -Dm644 LICENSE "$pkgdir/usr/share/licenses/${pkgname%-git}/LICENSE"
    install -Dm644 README.rst "$pkgdir/usr/share/doc/${pkgname%-git}/README.rst"
}

# vim: set et sw=4 ts=4 :