summarylogtreecommitdiffstats
path: root/PKGBUILD
blob: d61183ddf775e3a7f8864c0bcd4d255840d10e9b (plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
# Maintainer: Tinu Weber <http://ayekat.ch/>

pkgname=arachne-git
pkgver=r462.2c5cc16
pkgrel=1
arch=(x86_64)

pkgdesc='Core aware thread management system'
license=(unknown)
url='https://github.com/PlatformLab/Arachne/'

source=('git+https://github.com/PlatformLab/Arachne/'
        'makefile.diff')
sha256sums=(SKIP
            4ffa97a8a6b1e9fbf15c709a5c02a3bb13ef54ceb3c150d59345df57a75c2ed5)

provides=(arachne)
conflicts=(arachne)

makedepends=(git corearbiter perfutils)

options=(staticlibs)

pkgver() {
  cd Arachne
  printf 'r%s.%s' "$(git rev-list --count HEAD)" "$(git rev-parse --short HEAD)"
}

prepare() {
  cd Arachne
  patch -p1 -i "$srcdir"/makefile.diff
}

build() {
  cd Arachne
  make PERFUTILS=/usr COREARBITER=/usr \
       EXTRA_CXXFLAGS='-Wno-error=class-memaccess'
}

package() {
  cd Arachne

  # libraries
  install -Dm0644 lib/libArachne.a "$pkgdir"/usr/lib/libArachne.a

  # headers
  install -dm0755 "$pkgdir"/usr/include/Arachne
  install -m0644 include/Arachne/* "$pkgdir"/usr/include/Arachne/

  # misc
  install -Dm0644 README.md "$pkgdir"/usr/share/doc/"${pkgname%-git}"/README.md
}