summarylogtreecommitdiffstats
path: root/PKGBUILD
blob: 184729268038e8e55ae4576157e2103ffe629fa8 (plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
# Maintainer: Stefan Husmann <stefan-husmann@t-online.de>
# Contributor: Jonas Witschel <diabonas@archlinux.org>
pkgname=amide  
pkgver=1.0.6
pkgrel=6
pkgdesc='Medical imaging data examiner'
arch=('x86_64')
url='http://amide.sourceforge.net/'
license=('GPL')
depends=('dcmtk' 'ffmpeg' 'gsl' 'libgnomecanvas' 'volpack' 'xmedcon')
makedepends=('gtk-doc' 'gnome-doc-utils' 'intltool')
source=('https://web.stanford.edu/~loening/files/amide-1.0.6-2.fc25.src.rpm' amide_nognome.patch)
sha512sums=('2d6f9d7cfa7921ba95fd0a887504d4ec135d0e93d94ffdf256b5fc94f3df1766006e0f13ca24c1cc7904c636182db96b7e7c29ac2529554c351458217406053d'
            '34af3c04ff094fe942f02ff8603617f969415e1c4ebc1ef16fba0bcb6d4070285c5027a4212ec49d07e343ca141010507c284dd30b4884545e324411b116d37c')

prepare() {
  bsdtar --extract --file "$pkgname-$pkgver.tgz"
  cd "$pkgname-$pkgver"
  patch -Np2 < "$srcdir"/amide_nognome.patch
}

build() {
  cd "$pkgname-$pkgver"
  autoreconf -fi
  CFLAGS+=" -fcommon" ./configure \
	 --prefix=/usr \
	 --disable-gconf \
	 --disable-gnome-vfs
  make --jobs=1
}

package() {
  cd "$pkgname-$pkgver"
  make DESTDIR="$pkgdir" install
}