summarylogtreecommitdiffstats
path: root/PKGBUILD
diff options
context:
space:
mode:
Diffstat (limited to 'PKGBUILD')
-rw-r--r--PKGBUILD54
1 files changed, 54 insertions, 0 deletions
diff --git a/PKGBUILD b/PKGBUILD
new file mode 100644
index 00000000000..550155de848
--- /dev/null
+++ b/PKGBUILD
@@ -0,0 +1,54 @@
+# Maintainer: Sainnhe Park <sainnhe@gmail.com>
+_variant='vim'
+_colorscheme='gruvbox-material'
+
+pkgbase="${_variant}-${_colorscheme}-git"
+pkgname=("${_variant}-${_colorscheme}-git"
+ "${_variant}-airline-${_colorscheme}-git"
+ "${_variant}-lightline-${_colorscheme}-git")
+pkgver=v1.2.0.r12.g8c5607c
+pkgrel=1
+arch=('any')
+url="https://github.com/sainnhe/${_colorscheme}"
+license=('MIT')
+source=("${_colorscheme}::git+${url}.git")
+sha256sums=('SKIP')
+
+pkgver() {
+ cd "${srcdir}/${_colorscheme}"
+ git describe --long --tags | sed 's/\([^-]*-g\)/r\1/;s/-/./g'
+}
+
+package_vim-gruvbox-material-git() {
+ pkgdesc='Gruvbox with Material Palette'
+ depends=("${_variant}")
+ provides=("${_variant}-${_colorscheme}")
+ conflicts=("${_variant}-${_colorscheme}")
+ cd "${srcdir}/${_colorscheme}"
+ find autoload/*.vim doc colors -type f -exec \
+ install -Dm 644 '{}' "${pkgdir}/usr/share/vim/vimfiles/{}" \;
+ install -Dm 644 "${srcdir}/${_colorscheme}/LICENSE" \
+ "${pkgdir}/usr/share/licenses/${pkgname}/LICENSE"
+}
+
+package_vim-airline-gruvbox-material-git() {
+ pkgdesc="${_colorscheme} color scheme for airline"
+ depends=("${_variant}-${_colorscheme}"
+ 'vim-airline')
+ provides=("${_variant}-airline-${_colorscheme}")
+ conflicts=("${_variant}-airline-${_colorscheme}")
+ cd "${srcdir}/${_colorscheme}"
+ find autoload/airline -type f -exec \
+ install -Dm 644 '{}' "${pkgdir}/usr/share/vim/vimfiles/{}" \;
+}
+
+package_vim-lightline-gruvbox-material-git() {
+ pkgdesc="${_colorscheme} color scheme for lightline"
+ depends=("${_variant}-${_colorscheme}"
+ 'vim-lightline-git')
+ provides=("${_variant}-lightline-${_colorscheme}")
+ conflicts=("${_variant}-lightline-${_colorscheme}")
+ cd "${srcdir}/${_colorscheme}"
+ find autoload/lightline -type f -exec \
+ install -Dm 644 '{}' "${pkgdir}/usr/share/vim/vimfiles/{}" \;
+}